información DE SPED

INFORMACION "pl_hudinfo_espec"

//__________________________________________________________
// 
// INFORMACIÓN AL ESPECTEAR - V1.0 CREADO POR EMANUELITOP15
//__________________________________________________________

#include <amxmodx>
#include <hamsandwich>
#include <engine>
#include <cstrike>

new const PLUGIN[]  =    {"[HUD] Informacion al Espectear"};
new const VERSION[] =    {"1.0"};
new const CREADOR[] =    {"Emanuelitop15"};

new bool: g_vivo[MAX_PLAYERS+1], g_synchud;

#define TASK_HUD_ESPEC 77112
#define ID_HUD_ESPEC (taskid - TASK_HUD_ESPEC)

new cvar_hudinfo_espec, cvar_dhud;

public plugin_init()
{
	register_plugin(PLUGIN, VERSION, CREADOR);

	cvar_hudinfo_espec = create_cvar("hud_info_espectador", "1", _, "- Activa/Desactiva el HUD informativo al espectear a alguien.");
	cvar_dhud = create_cvar("hud_info_espectador_modo_dhud", "0", _, "- Muestre en formato DHUD el texto informativo al espectear a alguien.");

	RegisterHam(Ham_Killed, "player", "HAM_JUGADOR_ASESINADO", .Post = 1);
	RegisterHam(Ham_Spawn, "player", "HAM_JUGADOR_SPAWN", .Post = 1);

	g_synchud = CreateHudSyncObj();
}

public HAM_JUGADOR_SPAWN(id)
{
	if (!is_user_alive(id)) return;

	g_vivo[id] = true;
}

public HAM_JUGADOR_ASESINADO(victima, atacante)
{
	g_vivo[victima] = false;

	if (get_pcvar_num(cvar_hudinfo_espec))
	{
		remove_task(victima + TASK_HUD_ESPEC);
		set_task(0.2, "task_hud_espec", victima + TASK_HUD_ESPEC, _,_, "b");
	}
}

public task_hud_espec(taskid)
{
	if (g_vivo[ID_HUD_ESPEC] || !get_pcvar_num(cvar_hudinfo_espec))
	{
		remove_task(taskid);
		return;
	}

	new espec_id; espec_id = entity_get_int(ID_HUD_ESPEC, EV_INT_iuser2);

	if (g_vivo[espec_id])
	{
		mostrar_datos(ID_HUD_ESPEC, espec_id);
	}
}

mostrar_datos(id, id2)
{
	new txtfull[321], sz_arma[32];

	if (get_user_weapon(id2))
	{
			get_weaponname(get_user_weapon(id2), sz_arma, charsmax(sz_arma));

			replace_all(sz_arma, charsmax(sz_arma), "weapon_", "");
			replace_all(sz_arma, charsmax(sz_arma), "knife", "cuchillo");
			replace_all(sz_arma, charsmax(sz_arma), "hegrenade", "he");
			replace_all(sz_arma, charsmax(sz_arma), "flashbang", "flash");
			replace_all(sz_arma, charsmax(sz_arma), "smokegrenade", "humo");
	}

	format(txtfull, charsmax(txtfull), "[tucuGAMERS] - Información del Jugador^n^n\
	[Nombre: %n]^n\
	[Vida: %d | Chaleco: %d]^n\
	[Arma: %s]", id2, get_user_health(id2), get_user_armor(id2), sz_arma);

	if (get_pcvar_num(cvar_dhud))
	{
		set_dhudmessage(150, 150, 20, 0.01, 0.20, 0, 6.0, 0.2, 0.1, 0.019);
		show_dhudmessage(id, txtfull);
	}
	else
	{
		set_hudmessage(150, 150, 0, 0.01, 0.19, 0, 6.0, 0.21, 0.1, 0.2, -1);
		ShowSyncHudMsg(id, g_synchud, txtfull);
	}
}

Lo pueden editar a su manera 

Creado por Emanuel15